ich hoffe auf Eure Hilfe! Ich möchte sichergehen, dass Studierende von der 1. bis zur 4. Welle keinen Wechsel des Hochschultyps (also Wechsel zwischen Uni und FH) vorgenommen haben. Alternativ wäre es auch ok, wenn kein Wechsel der Hochschule an sich stattgefunden hat, man also an der gleichen Institution wie in der 1. Welle geblieben ist. Der Nachteil wäre hier aber natürlich, dass mehr Fälle wegfallen würden, weil ich die Fälle mit jeglichem Wechsel der Hochschule und nicht nur des Hochschultyps ausschließen würde.
Wäre hierfür die Variable tx24011 aus StudyStates geeignet? Meine Vermutung wäre, dass ich hier einfach schaue, wer von der 1. bis zur 4. Welle eine -20, also „kein Wechsel“, stehen hat und ich Fälle mit anderen Ausprägungen ausschließe (wobei mir die Ausprägungen wie XXXXX00, XXXXX01 etc. hier inhaltlich nicht klar sind…). Diese Variable betrifft ja den Wechsel zwischen Hochschulen, also nicht den Hochschultyp.
Eine äquivalente Variable die den Wechsel des Hochschultyps für die benötigten Wellen anzeigt, konnte ich leider nicht finden, habe ich da etwas übersehen?
Ich freue mich auf Eure Rückmeldung und bedanke mich im Voraus für Eure Unterstützung!!
Variable tg01003_ha umbenennen (z.B hstyp_pre HS-Typ vor Wechsel)
tx24021 in splink umbenennen ( Episodennummer vor HS-Typ-Wechsel)
als Arbeitsdatensatz1 speichern
wieder spVocTrain öffnen,
nun tg01003_ha analog als HS-Typ nach Wechsel umbenennen
tx24022 in splink umbenennen ( Episodennummer nach HS-Typ-Wechsel)
als Arbeitsdatensatz2 speichern
StudyStates öffnen
Arbeitsdatensatz1 via ID_t und splink anspielen
Arbeitsdatensatz2 via ID_t und splink anspielen
Dummy für HS-Typ-Wechsler generieren
Hier ist die Syntax - da ist auch noch die Alternative mit den Hochschulwechseln mit dabei.
Viel Spaß
Dietmar
***** Hochschultyp aus spVocTrain holen *****
use ID_t subspell splink tg01003_ha using "SC5_spVocTrain_D_15-0-0.dta", clear
keep if subspell == 0
clonevar tx24021 = splink // splink in tx24021 umbenennen
drop subspell splink
rename tg01003_ha hstyp_pre // hs-typ vor Wechsel
save "Y:/SC5_voctrain_tx24021.dta", replace
use ID_t subspell splink tg01003_ha using "SC5_spVocTrain_D_15-0-0.dta", clear
keep if subspell == 0
clonevar tx24022 = splink // splink in tx24022 umbenennen
drop subspell splink
rename tg01003_ha hstyp_post // hs-typ nach Wechsel
save "Y:/SC5_voctrain_tx24022.dta", replace
***** StudyStates vorbereiten *****
use "SC5_StudyStates_D_15-0-0.dta", clear
** falls erwünscht: Hochschulwechsel als Auswahlkriterium **
bysort ID_t : egen max_hsnr = max(tx24011) if wave <= 4 // Maximalwert für HS-ID pro Person berechnen >> wenn Zahl größer als Null, dann gibt es einen Wechsel bis Welle 4
// Hochschulwechsel-Dummy erzeugen für Welle <= 4
generate hs_change = (max_hsnr > -20) if wave <= 4
replace hs_change = -55 if missing(max_hsnr) & wave <= 4
replace hs_change = - 21 if wave > 4
label define hs_change_lb -55"nicht ermittelbar" -21"Welle > 4" 0"Nein" 1"Ja"
label value hs_change hs_change_lb
// Alle Personen in allen Wellen als HS-Wechsler markieren, die bis Welle 4 HS wechselten
bysort ID_t: egen any_hs_change = max(hs_change)
label value any_hs_change hs_change_lb
//drop if any_hs_change
** Ende alternatives Auswahlkriterium Hochschulwechsler **
// hstyp_pre mit Episodennummer vor Wechsel an StudyStates anspielen
merge m:1 ID_t tx24021 using "Y:/SC5_voctrain_tx24021.dta", keep(master matched)
// hstyp_post mit Episodennummer vor Wechsel an StudyStates anspielen
merge m:1 ID_t tx24022 using "Y:/SC5_voctrain_tx24022.dta", keep(matched) nogenerate
// Wechsel des HS-Typs bis einschl. Welle 4 markieren
generate hstyp_change = ((hstyp_pre != hstyp_post) & (inlist(hstyp_pre,1,2) & inlist(hstyp_post,1,2)) & wave <= 4)
// Alle Personen in allen Wellen als HS-Typ-Wechsler markieren, die bis Welle 4 den HS-Typ wechselten
bysort ID_t (wave): egen any_hstyp_change = max(hstyp_change)
// Diese Wechseler ausschließen
drop if any_hstyp_change
Ich kann die Syntax nachvollziehen. Mir hat sich aber noch die Frage aufgetan, wie ich mir den jeweiligen Hochschultyp für die einzelnen Wellen anschauen kann, also unabhängig davon ob ein Wechsel stattgefunden hat oder nicht. Konkret möchte ich erfahren, welche Studierenden in Welle 4 an einer Uni/FH studieren, ohne zu berücksichtigen ob sie davor oder danach evtl. gewechselt haben/wechseln werden.
Mir fällt die Arbeit die Arbeit mit den spell- und long-Datensätzen noch etwas schwer, deshalb herzlichen Dank für Deine Mühe und Unterstützung!
Viele Grüße
Ami
/* StudyStates
- öffnen
- tx24022 in splink umbenennen
- Datensatzt als temporären Datensatz speichern
*/
use ID_t wave tx24022 using "SC5_StudyStates_D_15-0-0.dta", clear
rename tx24022 splink
tempfile studystates_tmp
save "`studystates_tmp'", replace
/* spVocTrain
- relevante Variablen aus spVocTrain öffnen
- nur harmonisierte Episoden behalten
- subspell droppen (kann man, muss man aber nicht)
*/
use ID_t splink subspell tg01003_ha using "SC5_spVocTrain_D_15-0-0.dta", clear
keep if subspell == 0
drop subspell
/* den temporäre StudyStates-Datensatz an spVocTrain anspielen
>> 1:m - merge, weil sich eine Episode über mehrere Wellen einer Person erstrecken kann
>> keep(matched), weil nur Episoden, die in beiden Datensätzen vorhanden sind, betrachtet werden können
- >> wieder als temp. Datei speichern (wenn man noch Datan aus dem CAWI hinzufugen will)
*/
merge 1:m ID_t splink using "`studystates_tmp'", keep(matched) nogenerate
tab wave tg01003_ha
tempfile studystates_spvoc_tmp
save "`studystates_spvoc_tmp'", replace
/* -Variable für Hochschulart aus pTargetCAWI fischen und relevante Variablen laden
- nur Personen behalten, die entweder an Uni oder FH studieren
- merge mit studystates_spvoc_tmp
- Variable hs_typ generieren (=Klon von tg01003_ha)
- missings in hs_type durch gültige Werde aus pTargetCAWI ersetzen
*/
use ID_t wave tg51003 using "SC5_pTargetCAWI_D_15-0-0.dta", clear
keep if inlist(tg51003,1,2)
merge 1:1 ID_t wave using "`studystates_spvoc_tmp'"
clonevar hs_typ=tg01003_ha
replace hs_typ = tg51003 if missing(hs_typ)
tab wave hs_typ