SC1 - Verteilung Elternzeitvariable

Liebes NEPS-Team,
ich habe die Variablen total_parleave und total_parleave_partner wie im Data Manual beschrieben erstellt, gemerged und nach Geschlecht getrennt für Mütter und Väter neue Variablen generiert.
Was mich etwas verwundert hat, ist die Verteilung der Variable für die Dauer der Elternzeit des Vaters und hier besonders der höhere Wert für 3 monatige Elternzeit (1676 Beobachtungen) im Vergleich zu 2 Monaten (1649 Beobachtungen).
Zwar ist die Anzahl der Väter mit 2 Monaten Elternzeit (325 distinct IDs) leicht höher als die mit 3 Monaten (318 distinct IDs), dennoch wollte ich nachfragen, ob das mit Ihren Ergebnissen übereinstimmt oder ob wegen der Ereignisdatenstruktur der Elternzeitvariablen zusätzlich etwas beachtet werden muss?
Vielen Dank und beste Grüße

Hallo,

die Zahl der Beobachtungen direkt miteinander zu vergleichen, ist nur begrenzt sinnvoll, weil manche der Befragten mehrmals Angaben zur Elternzeit gemacht haben. Wenn ich es richtig verstehe, interessierst du dich für die Gesamtanzahl der Monate, die eine Person in Elternzeit verbracht hat. Um die (nach Geschlecht getrennt) herauszubekommen, kannst du zum Beispiel folgendermaßen vorgehen:

  1. Eine Variable zur aufsummierten Elternzeit der Befragungsperson bilden und an den pParent-Datensatz mergen.
  2. Eine Variable zur aufsummierten Elternzeit des Partners/der Partnerin bilden und an den unter 1. erstellen Datensatz mergen. Im Ergebnis erhältst du einen Längsschnitt-Datensatz mit mehreren Zeilen pro Kind für die unterschiedlichen Wellen. Die Informationen aus den Datensätzen spParLeave und spPartnerParLeave stehen jeweils in Zeilen der Welle 2 bzw. Welle 4, weil nur in diesen Wellen nach der Elternzeit gefragt wurde.
  3. Eine Variable „leave_male“ bilden, die die Elternzeit der männlichen Befragungsperson bzw. des männlichen Partners enthält.
  4. Bei fehlenden Werten in Welle 2 die Informationen aus Welle 4 übernehmen.
  5. Nur eine Zeile pro Kind behalten (in diesem Fall Welle 2).
  6. Eine Häufigkeitstabelle zu „leave_male“ ausgeben.

Einen Beispielcode für STATA habe ich dir hier angehängt. Im Ergebnis geben etwas mehr männliche Personen an, 2 Monate Elternzeit genommen zu haben (n = 320). Die Anzahl derjenigen mit 3 Monaten Elternzeit rangiert allerdings nur knapp dahinter (n = 313).

Ich hoffe, das beantwortet deine Frage.

Weiterhin gutes Gelingen,
Hannah

*********** Elternzeit Befragungsperson - Datensatz vorbereiten und mergen *********

use SC1_spParLeave_D_6-0-0.dta, clear
label language en

keep if subspell == 0

gen ep_start = ym(pa0403y, pa0403m)
gen ep_end = ym(pa0404y, pa0404m)

gen duration = ep_end - ep_start + 1

egen total_parleave = sum(duration), by(ID_t)
fre total_parleave

keep ID_t wave total_parleave
duplicates drop

tempfile temp
save `temp'

use SC1_pParent_D_6-0-0.dta, clear
label language en

merge 1:1 ID_t wave using `temp', keep(master match) nogen
keep  ID_t wave total_parleave p731702 p731116
save pparent_merged.dta, replace



*********** Elternzeit Partner - Datensatz vorbereiten und mergen *********

use SC1_spPartnerParLeave_D_6-0-0.dta, clear
label language en

keep if subspell == 0

gen ep_start = ym(pa0503y, pa0503m)
gen ep_end = ym(pa0504y, pa0504m)

gen duration = ep_end - ep_start + 1

egen total_parleave_partner = sum(duration), by(ID_t)

keep ID_t wave total_parleave_partner
duplicates drop

tempfile temp
save `temp'

use pparent_merged.dta, clear
label language en

merge 1:1 ID_t wave using `temp', keep(master match) nogen
keep ID_t wave total_parleave total_parleave_partner p731702 p731116
save pparent_merged_2.dta, replace



*********** Elternzeit bei männlichen Befragten/Partnern *********

use pparent_merged_2.dta, clear
sort ID_t wave

gen leave_male = 0
replace leave_male = total_parleave if p731702 == 1
replace leave_male = total_parleave_partner if p731116 == 1 & p731702 == 2 /* entsprechend Simones Anmerkung angepasst */

keep if (wave == 2 | wave == 4)

* Bei Missings in Welle 2 werden die Informationen aus Welle 4 übernommen:
by ID_t: generate sn = _n
bysort ID_t (wave): replace leave_male = leave_male[_n+1] if missing(leave_male)

keep if sn == 1 /* nur Welle 2 behalten */

drop if ID_t == 8065296 /* Enddatum der Partnerepisode liegt vor Startdatum. Fehlerquelle nicht eindeutig, daher wird der Fall gelöscht */

fre leave_male

Hier noch ein Nachtrag dazu, weshalb die relativen Häufigkeiten etwa von Angaben des Statistischen Bundesamtes abweichen:

Dass die Dauern der Elternzeit im NEPS so stark von den Zahlen des Statistischen Bundesamtes abweichen, liegt vermutlich an der Selektivität des Panels, also daran, dass nach einigen Wellen vor allem noch Personen mit höherem sozioökonomischen Status an der Studie teilnehmen.

Eine Selektivitätsanalyse für die SC1 findet sich zum Beispiel im Bericht zum aktuellen SUF in Tabelle 4 auf Seite 5.

Die Analyse zeigt, dass im Vergleich zur Grundgesamtheit überdurchschnittlich viele Kinder von Eltern mit vergleichsweise hoher Bildung an der Studie teilnehmen. Gleiches gilt für den Erwerbsstatus der Eltern: Wie sich der Tabelle entnehmen lässt, haben Kinder von erwerbstätigen Eltern ab Welle 3 über alle Wellen eine hochsignifikant höhere Neigung zur Teilnahme als andere Kinder.

Wir können deshalb davon ausgehen, dass die befragten Eltern im Vergleich zur Grundgesamtheit durchschnittlich über etwas höhere Bildung verfügen und auch finanziell besser dastehen. Das ist vermutlich der Grund dafür, dass männliche Befragungspersonen und Partner in der Studie im Vergleich zu den Zahlen des Statistischen Bundesamtes so viel häufiger angeben, 3 Monate Elternzeit genommen zu haben.