Hallo Simone,
zum ersten Teil deiner Frage: Es spricht meines Erachtens nichts Grundlegendes dagegen, die beiden Maße aus den unterschiedlichen Messzeitpunkten der Lesekompetenz gemeinsam zu verwenden, solange du in einer multivariaten Analyse einen Dummy für den jeweiligen Messzeitpunkt als Kontrollvariable berücksichtigst.
In der zweiten Frage bin ich etwas skeptischer; eine klare Kausalaussage kannst du auf Basis der abhängigen Variable „Berufsprestige in Welle 6“ nicht treffen. Relevant für eine Aussage, wie du sie vorhast zu treffen, ist viel mehr die Übergangswahrscheinlichkeit in ein höheres Prestige-Niveau zeitlich nach der Messung des Lesekompetenz. Denn ein hohes Berufsprestige in Welle 6 kann ja bereits seit langem (auch vor dem Messzeitpunkt der Lesekompetenz) bestanden haben. Ich denke, die Operationalisierung der abhängigen Variable ist der Kernpunkt, um eine Aussage, wie sie dir vorschwebt, sinnvoll treffen zu können.
Zum Punkt 3: Ich vermute, du hast bei der schnellen Auswertung der Daten nicht die Episodenstruktur der Erwerbs-Biographiedaten in spEmp berücksichtigt.Die Zahlen, die du nennst, spiegeln die Anzahl der Erwerbsepisoden, die in Welle X berichtet wurden wieder. Das ist nicht zu verwechseln mit Episoden, zu zum Interviewzeitpunkt in Welle X andauern. Gerade im Erstinterview mit neuen (aufgefrischten) NEPS-Befragten werden ja alle bisherigen Erwerbserfahrungen retrospektiv abgefragt; naturgemäß entstehen dabei deutlich mehr berichtete Episoden, als nur bei der Abfrage von neuen Ereignissen seit dem letzten Interview (das im Normalfall ja nur etwa 12 Monate zurückliegt).
Die folgende Stata-Syntax illustriert die Reduktion der Episodendaten auf eine Zeile pro Interviewzeitpunkt, und spielt dieser „normalen“ Panelstruktur den zum Interviewzeitpunkt gültigen höchsten EGP-Code an. Ich hoffe, damit wird etwas klarer, wie die Episodendaten sinnvoll zu reduzieren sind, um sie mit Panel- oder Querschnittsdaten zu verbinden und entsprechend eine Analyse zu fahren. Der Schlüssel liegt, wie gesagt, in der Reduktion der Daten, und einem Zuspielen über den Interviewmonat, nicht die Wellenvariable.
// This do-file requires -nepsuse-, a helper package to seamlessly open NEPS SUF datasets in Stata;
// obtain -nepsuse- (and a few other supporting packages) via
// . net install nepstools , from(http://nocrypt.neps-data.de/stata)
* set up information for -nepsuse-
* adjust file path to your setup
*global NEPSuse_directory "path/to/NEPS/SUFS"
global NEPSuse_cohort SC6
global NEPSuse_version 8.0.0
global NEPSuse_level D
global NEPSuse_language en
* we will need some temporary variables and datasets, so tell Stata
tempfile spEmp_infos biography
tempvar expandmarker
* open up Biography dataset
nepsuse `"Biography"' , clear
* restrict episodes to employment episodes
keep if sptype==26
* bloat up dataset to one observation per month
generate startdate=ym(starty,startm)
generate enddate=ym(endy,endm)
drop if (missing(enddate) , missing(startdate)) // we can't use episodes without date information
generate duration=enddate-startdate+1
expand=duration , generate(`expandmarker')
generate month=.
generate monthnum=.
bysort ID_t splink (`expandmarker') : replace monthnum=_n-1
replace month=startdate+monthnum
format startdate enddate month %tm
* double check and drop temporary variable
assert startdate==month if (!`expandmarker')
assert enddate==month if (!`expandmarker'[_n+1] , missing(`expandmarker'[_n+1]))
drop `expandmarker'
* temporarily save, and merge via date variable [sic!] to panel dataset
save `"`biography'"'
nepsuse `"pTarget"' , clear
keep ID_t wave intm inty
/* 'splink' may already exist in the dataset; we want to recreate it linking to not only spEmp episodes */
capture : confirm variable splink , exact
if (_rc==0) drop splink
generate month=ym(inty,intm)
label variable month `"month of interview date"'
format month %tm
* workaround: there are a few inconsistent interview dates from wave 7 in SC6 8.0.0
replace month=ym(2014,12) if month==ym(2015,12) & wave==7
* merge with biography, and keep matching episodes
merge 1:m ID_t month using `"`biography'"' , nogenerate keepusing(splink sptype) keep(match) // we don't need observations without a single spell information
* result: a panel dataset with one observation per censored episode per wave
isid ID_t splink wave
/*
from now on, several observations per wave are contained in the dataset,
one for each episode that is ongoing (=censored) during the interview;
before an analysis can start, these should be reduced to one observation per wave,
depending in the interest of the analysis, possibly taking into account
information from the episodes' spell files
*/
/* =========================== STOP ===========================
HERE BEGINS THE PART WHERE A DECISION FOR
DE-DUPLICATION HAS TO BE MADE, DEPENDING
ON THE RESEARCH INTEREST!
=========================== STOP =========================== */
* merge focal variables from any content spell file, and reduce sample
/* this of course has to be customized depending on interest */
preserve
nepsuse ID_t splink subspell spms ts23201_g8 using `"spEmp"' , clear
keep if subspell==0 // only use harmonized and complete episodes
save `"`spEmp_infos'"'
restore
keep if sptype==26 // only keep observations with ongoing employment episodes
merge m:1 ID_t splink using `"`spEmp_infos'"' , nogenerate keepusing(ts23201_g8) keep(match) // we don't need Employment spells not matching the interview date or from unwanted EGP classes
duplicates report ID_t wave // still several employment episodes for some persons
* --> reduce to 'highest' EGP class inside wave for each person (careful, EGP is cross-coded!)
nepsmiss ts23201_g8
bysort ID_t wave : egen egpclass=min(ts23201_g8)
drop if missing(egpclass)
label values egpclass `: value label ts23201_g8'
label variable egpclass "highest EGP class at interview date"
* --> remove duplicates afterwards
drop splink ts23201_g8 sptype
duplicates drop
* --> no we're in a 'regular' panel structure again: one observation per id per wave
isid ID_t wave
/* ^^ this checks that the data format is truly in panel form ^^ */
exit
// EOF
Beste Grüße
Bela