Übertragen von -54 (missing by design) Werten zur Behinderung aus anderen Wellen

Hallo,
gerade stelle ich meinen Datensatz mit dem Unterthema Behinderung in SC6 Welle 4 zusammen. Dabei ist mir aufgefallen, dass bei Welle 4 die Behinderungs-Variablen zu ca. 75% die Werte auf -54 (missing by design) stehen. Das betrifft die von mir verwendeten:

  • t524200: Anerkannte Behinderung
  • t524205: Behinderungsgrad
  • t524204: Jahr Anerkennung Behinderung

Dank der Dokumentation, den Informationen im NEPSplorer und der anderen Posts hier im Forum gehe ich davon aus, dass dies daran liegt, dass diese Variablen nicht nur in Welle 4, sondern auch Welle 2 und Welle 8 abgefragt wurden.

Würden bei Kombination der Variable aus den 3 Wellen-Dateien die -54 verschwinden?

Darf ich als NEPS-Anfänger fragen, ob es dazu bereits eine bewährte Methode gibt; so dass ich mir alle Informationen zur Behinderung in die Welle 4 übertragen kann (ich arbeite mit R; kann aber event. auch eine Stata-Idee „übersetzen“).

Eine methodische Frage noch: Wird die Behinderung, Behinderungsgrad und (neues) Jahr noch einmal erhoben? Innerhalb von mehreren Jahren kann sich da ja z.B. durch einen Unfall oder eine erweiterte Diagnose noch etwas ändern.

Gerade die Fälle einer spät eintretenden Behinderung sind nämlich für meine Fragestellung interessant.
Oder gibt es dazu noch einen separaten Episodendatensatz, in dem ich über den NEPSplorer den Aspekt Behinderung nicht gefunden habe?

Vielen herzlichen Dank

Simon

Hallo Simon!

Ja, die Variable wird in den Wellen 2, 4 und 8 abgefragt.
Wenn man mal die Variable tx80211 betrachtet, kann man erkennen, dass in Welle 2 sowohl Panel- als auch Erstbefragte im CATI mit der Frage konfrontiert wurden. In Welle 4 hingegen nur Erstbefragte.

 ID_t tx80211 wave t524200 t524205 t524204 using "pTarget.dta", clear

// mit tx80211 überprüfen, wann die Personen mit der Frage konfrontiert wurden.
tab tx80211 if (t524200 != -54) & wave == 2  // alle Personen erhalten die Frage
tab tx80211 if (t524200 == -54) & wave == 2 // es gibt demnach kein Design-Missing

tab tx80211 if (t524200 != -54) & wave == 4 // nur Erstbefragte erhalten die Frage
tab tx80211 if (t524200 == -54) & wave == 4  // nut Panelbefragte haben Design-Missing

tab tx80211 if (t524200 != -54) & wave == 8 // alle Personen erhalten die Frage
tab tx80211 if (t524200 == -54) & wave == 8 // es gibt demnach kein Design-Missing

Wenn du nur diese Wellen behältst und den Datensatz dann einfach ins wide-format reshapest, hast du für jede Welle und für jedes Item eine Variable - also insgesamt neun.

// System-Missings in t524205 t524204 mit Trifft nicht zu ersetzen, wenn keine Behinderung vorliegt
replace t524204=-93 if t524200==2 & missing(t524204)
replace t524205=-93 if t524200==2 & missing(t524205)

// Vorbereitung zum Reshape
foreach var of varlist t524200 t524205 t524204 {
	replace `var'= .x if `var'==-54   // missings als echte missings kodieren
	replace `var'= .y if `var'==-97 | `var' == -98 // missings als echte missings kodieren
	replace `var'= .z if `var'==-93  // missings als echte missings kodieren
	label define `: value label `var'' .x"missing by design" .y"refused/no answer" .z"does not apply", modify  // missings mit Wertelabel versehen
}

rename (t*) (t*_w) // Variable umbenennen: mit _w-Suffix kann man die wide-Variablen besser lesen

keep if inlist(wave,2,4,8) // Nur die benötigten Welle behalten
reshape wide t524200_w t524205_w t524204_w tx80211_w, i(ID_t) j(wave)  // reshape ins wide-format

Wenn man nun ganz stupide die fehlenden Werte aus den einzelnen Wellen mit den gültigen Werten aus den anderen Welle ersetzt, bleiben nur noch 80 Personen übrig, die nicht gefragt wurden, ob sie ein Behinderung haben. Wenn du die Welle 4 mit anderen (zeitveränderlichen) Variablen in Bezug setzen willst, solltest, du nur Fälle verwenden, bei denen das Jahr der Anerkennung jünger oder gleich dem Jahr des Interviews in Welle 4 ist.

// Stupide gemeinsame Variable für alle 3 Wellen generieren: Achtung - bitte anpassen, ist nur eine grobe Heuristik, vielleicht sollte man auch erst Werte aus Welle 4 nehmen...
* - zuerst Werte auch Welle 8 Wählen, dann die Fälle mit Missings aus vergangenen Welle auffüllen
generate t524200_all = t524200_w8
 replace t524200_all = t524200_w4 if missing(t524200_all)
 replace t524200_all = t524200_w2 if missing(t524200_all)

generate t524204_all = t524204_w8
 replace t524204_all = t524204_w4 if missing(t524204_all)
 replace t524204_all = t524204_w2 if missing(t524204_all)

generate t524205_all = t524205_w8
 replace t524205_all = t524205_w4 if missing(t524205_all)
 replace t524205_all = t524205_w2 if missing(t524205_all)

// Wertelabel aus der Variable der Welle 2 übernehmen
label values t524200_all `: value label t524200_w2' 
label values t524204_all `: value label t524204_w2'
label values t524205_all `: value label t524205_w2' 

Wenn man schon alle Werte einer Person in einer Zeile hat, kann man auch ganz einfach per Kreuztabellen feststellen, dass Personen mehrfach zu Behinderungen befragt wurden. Für Welle 2 und Welle 4 gibt es keine Schnittmenge, für Welle 2 vs. 8 und Welle 4 vs. 8 schon. Zwischen den Wellen wechselt der Status Behinderung Ja/Nein bei einigen Befragten. Man kann sich dann auch noch ansehen, auch bei Grad und Annerkennungsjahr gibt es Unterschiede. das Wording im Fragebogen der Welle 8 lässt jetzt auch nicht darauf schließen, dass explizit nach neu erfolgten Behinderung gefragt wurde.

Wenn du im Explorer keine Variablen zu Behinderungen in den Episodendaten gefunden hast, dann gibt’s dazu wahrscheinlich nix :slight_smile:

Viele Grüße
Dietmar

1 „Gefällt mir“

Vielen Dank für die ausführliche Antwort Dietmar!

Das hilft mir sehr weiter.

Dann gehe ich sicherheitshalber davon aus, dass zumindest nicht systematisch neue Behinderungen abgefragt werden, sondern nehme den letzten Status vor meinem Ausgangs-Jahr her.

Beste Grüße

Simon