in Welle 5 werden die Jugendlichen der SC4 zu politischen Aktionen befragt. Für meine Analysen ist notwendig, dass genaue Interviewdatum in Welle 5 für diese Personen zu haben.Hierzu habe ich an mein Masterfile (pTarget) das Interviewdatum aus TargetMethods angespielt und musste feststellen, dass bei denjenigen, die an der Erhebung zur politischen Teilhabe teilgenommen haben, keine Informationen über das Interviewdatum vorliegen.
Woran könnte das liegen?
neps: use pTarget
keep ID_t wave t516005 t700031
nepsmiss _all
keep if wave==5
isid ID_t
save "C:\Daten\Civic Engagement\pTarget.dta", replace
***Interviewdatum
clear
neps: use TargetMethods
keep ID_t wave intm inty
nepsmiss _all
keep if wave==5
isid ID_t
gen intd = ym(inty,intm)
format intd %tm
lab var intd "Interviewdatum"
save "C:\Daten\Civic Engagement\interviewdatum.dta", replace
*** MERGEN
clear
use "C:\Daten\Civic Engagement\pTarget.dta", replace
merge 1:1 ID_t wave using "C:\Daten\Civic Engagement\interviewdatum.dta", /// keep (master match) nogenerate
Sorry, dass du solange warten musstest, das war keine Absicht!
Ich habe mir das Problem angesehen. Das Problem ist, dass in TargetMethods nur das Interviewdatum aus den CATI-Befragungen steht, also aus Daten von pTargetCATI. Es gibt aber die Möglichkeit das Datum der Kompetenztestung zu verwenden falls auch eine Befragung vorliegt.
Im folgenden Code habe ich deine Syntax um diesen Schritt ergänzt.
Ich hoffe, das hilft dir weiter?
In Zukunft versuche ich zügiger zu Antworten.
Viele Grüße
Dietmar Angerer
use "SC4_pTarget_D_10-0-0.dta" , clear
keep ID_t wave t516005 t700031
nepsmiss _all
keep if wave==5
isid ID_t
tempfile pTarget_tmp
save "`pTarget_tmp'", replace
*************************
// Datum der Kompetenztestung als Interviewdatum verwenden, wenn auch ein Interview vorliegt (tx80521==1)
use ID_t wave test* tx80220 tx80522 tx80521 using "SC4_CohortProfile_D_10-0-0.dta" , clear
gen inty=testy_w1 if (testy_w1 > 0 & !missing(testy_w1) & tx80521==1)
replace inty=testy_w2 if (testy_w2 > 0 & !missing(testy_w2) & tx80521==1 & missing(inty))
gen intm=testm_w1 if (testm_w1 > 0 & !missing(testm_w1) & tx80521==1)
replace intm=testm_w2 if (testm_w2 > 0 & !missing(testm_w2) & tx80521==1 & missing(intm))
gen intd = ym(inty,intm)
format intd %tm
drop test* intm inty
keep if wave==5 & !missing(intd)
tempfile cohortdate_tmp
save "`cohortdate_tmp'", replace
*************************
***Interviewdatum
use "SC4_TargetMethods_D_10-0-0.dta" , clear
keep ID_t wave intm inty
nepsmiss _all
keep if wave==5
isid ID_t
gen intd = ym(inty,intm)
format intd %tm
lab var intd "Interviewdatum"
tempfile intdate_tmp
save "`intdate_tmp'", replace
*** MERGEN
clear
use "`pTarget_tmp'", clear
merge 1:1 ID_t wave using "`intdate_tmp'", keep (master match) nogenerate
count if !missing(intd)
// Update-Merge mit den generiertem Interviewdatum aus CohortProfile (bestehende Missings in inty werden mit gültigen Werten überschrieben)
merge 1:1 ID_t wave using "`cohortdate_tmp'", keep (1 3 4) nogen update replace
count if !missing(intd)