Nettoäquivalenzeinkommen

Guten Tag,

 ich nutze den NEPS Datensatz der 2. Startkohorte und wollte fragen, ob euch für diesen Datensatz eine STATA Funktion vorliegt, mit der ich das Äquivalenzeinkommen, also das gewichtete Haushaltsnettoeinkommen, berechnen kann.

Vielen Dank!

Wenn ich es richtig verstehe, möchten Sie das bedarfsgewichtete Äquivalenz-Einkommen nach der OECD-Skala berechnen. Eine vorgefertigte "Stata-Funktion" gibt es dafür nicht; allerdings ist die Berechungsformel relativ einfach: <HH-Einkommen>/(1+((<HH-Mitglieder über 13>-1)*0.5)+(<HH-Mitglieder unter 14>*0.3))

Alle zur Berechnung notwendigen Variablen werden im Interview erfasst, die relevanten Variablen sind:
p742040 (Zielkind lebt im gleichen Haushalt?)
p741001 (Haushaltsgröße)
p742001 (Personen unter 14 im Haushalt)
p510001 (Haushaltseinkommen -- alte Formulierung Welle 1)
p510005 (Haushaltseinkommen -- neue Formulierung ab Welle 2)

Der folgende Stata-do-file-Schnipsel illustriert die Berechnung anhand SC2 Version 6.0.0 (doi:10.5157/NEPS:SC2:6.0.0). Er verwendet unsere Stata-Hilfsprogramme "nepsmiss" und "nepsuse" aus dem Paket "nepstools" -- installierbar in Stata über den Befehl

net install nepstools , from(http://nocrypt.neps-data.de/stata)
nepsuse pParent , cohort(SC2) version(6.0.0) clear

// Eltern-Interviews mit Eltern, die nicht im gleichen Haushalt leben wie das Zielkind, sind hier nicht sinnvoll verwertbar
drop if p743040==2

// Haushaltseinkommen berechnen
generate hhinc=cond(p510001==-54,p510005,p510001)
label variable hhinc "Haushalts-Einkommen"
label copy `:value label p510001' hhinc_lbl
label values hhinc hhinc_lbl


// Personen im Haushalt unter 14 berechnen
clonevar hh_u14=p742001

// Personen im Haushalt über 13 berechnen
nepsmiss p741001 p742001
generate hh_o13=p741001-p742001 if (!missing(p741001) &amp; !missing(p742001))
label variable hh_o13 "Personen im Haushalt über 13"

// Bedarf berechnen
generate consumption=1+((hh_o13-1)*0.5)+(hh_u14*0.3)
label variable consumption "Äquivalenzbedarf des Haushalts"

// missing values weg-kodieren
nepsmiss hhinc hh_u14 hh_o13 consumption

// OECD-gewichtetes Haushaltseinkommen berechnen
generate oecdinc=hhinc/consumption
label variable oecdinc "bedarfsgewichtetes Netto-Äquivalenzeinkommen (OECD neu)"

// Plot der sich ergebenden Variable
histogram oecdinc , by(wave) frequency discrete



Naturgemäß beinhaltet die berechnete Variable möglicherweise unplausible hohe Werte, denn auch im ursprünglich berichteten Haushaltseinkommen finden sich die Entsprechungen dazu. Es ist ggf. sinnvoll, einen Cut-Off zu setzen, ab dem das Haushaltseinkommen als unplausibel (wegen Interviewfehler oder ähnlichem) angesehen wird. Wo genau dieser Cut-Off zu setzen ist, ist allerdings abhängig von der jeweiligen Analyse.

Beste Grüße

1 „Gefällt mir“