SC4: Fehlende Daten SpEmp

, , , ,
#1

Liebes NEPS-Forum,

ich nutze die beiden Datensätze Biography (Masterfile) und SpEmp und möchte zusätzliche Informationen über Fälle mit dem sptype=26 (Erwerbstätigkeit) an das Masterfile heranspielen, so zum Beispiel die berufliche Stellung. Nun fehlen leider sehr oft Werte zur beruflichen Stellung sodass Episoden mit sptype=26 mit den gemergten Variablen nicht konkretisiert werden können. Ich habe stichprobenartig mal das Datenfile SpEmp für einige Fälle geprüft und diese Informationen liegen tatsächlich nicht vor. Woran liegt das bzw. gibt es eine Möglichkeit die Erwerbstätigkeit hinsichtlich der Merkmale "Berufliche Stellung" zu spezifizieren?

***Zuvor: Aufbereitung des Biography Datenfiles***

* Auxiliary variable for merging 
gen subspell = 0     

*** spelltype: Employment
label language de
merge 1:m ID_t splink subspell using "${data}\SC4_spEmp_D_${SUF}.dta", ///
 nogen keep(1 3) keepusing(ts23203 ts23911 ts23218 ts23216 ts23217 ts23240_g1 ts23243)

nepsmiss ts23203 ts23911 ts23218 ts23216 ts23217 ts23240_g1 ts23243
fre ts23203 ts23911 ts23218 ts23216 ts23217 ts23240_g1 ts23243 if sptype==26

Edit DS: Tags hinzugefügt

#2

Hallo Robin!

Die Anzahl der Angaben ist so schon ok, schließlich haben zum jetzigen Zeitpunkt erst wenige Zielpersonen eine Ausbildung beendet und "landen" im spEmp.

Ich habe noch ein paar Tips. Den Biography zu laden und dann gen subspell=0 auszuführen ist nicht empfehlenswert, da subspell keine merging-Variable ist, sondern splink. Also zuerst im spEmp, wie auch in jedem anderen Episodendatensatz, nur die harmonisieren und/oder vollständigen Episoden behalten (keep if subspell==0) und dann erst mit merge 1:1 ID_t splink anspielen. Andernfalls gibt es Episoden-Duplikate.

Ich habe da unten  noch ein Beispiel. Ich hoffe, ich konnte etwas weiterhelfen.

Viele Grüße.

Dietmar

 

// NEPS-Stata-Pakete laden ...
net install nepstools, from(http://nocrypt.neps-data.de/stata)
net install nepsmgmt, from(http://nocrypt.neps-data.de/stata)

// nutze neps anstatt nepsuse
neps set study SC4
neps set version 9.1.1
neps set level D
neps set directory G:/work/NEPS/Daten/SC4_9-1-1

// Global für spEmp-Variablen definieren
global spEmpvars ts23203 ts23911 ts23218 ts23216 ts23217 ts23240_g1 ts23243

clear
neps: use Biography  // Biographhy laden
preserve // (bearbeiteten) Biography im Speicher sichern und später daran weiterarbeiten
	clear
	neps: use ID_t splink subspell ${spEmpvars} using "spEmp" // spEmp laden
	keep if subspell==0 // nur harmonisierte und abgeschlossene Episoden behalten
	drop subspell // wird nicht mehr gebraucht
	tempfile spEmp_tmp // tempfile für bearbeiteten spEmp definieren
	
        save "`spEmp_tmp'", replace // temporäres spEmp-File speichern
        // ACHTUNG: tempfiles funktionieren nur innerhalb eines do-file-Durchlaufes, also dofile komplett ausführen
restore // nun wird wieder das Biography-File geladen

  
// Biography und spEmp als 1:1-merge mit ID_t splink anspielen
merge 1:1 ID_t splink using "`spEmp_tmp'", /// 
	keepusing(${spEmpvars}) keep(master match) nogenerate

nepsmiss ${spEmpvars}
fre  ${spEmpvars} if sptype==26