Liebe Ann-Kathrin,
der Übergang von der Schule in die Ausbildung wird im NEPS sehr detailliert erhoben. Das NEPS ermöglicht es dadurch beispielsweise, den Übergang im Längschnitt von Berufswunsch über Bewerbungsverhalten bis hin zur realisierten Ausbildung nachzuzeichnen wie das beispielsweise Schels, Kleinert und Kolleginnen machen (2020, 2022). Wie genau du den Übergang operationalisierst, hängt also vor allem von deiner Fragestellung ab.
Die Grundinformationen zum Lebensverlauf, also der tatsächlich realisierte Übergang, werden längsschnittlich in einem Episodenformat erhoben. In den SUF-Daten liegen die Daten im spell-Format in den Files mit sp-Präfix (Zur beruflichen Bildung: spVocTrain-Datenfile). Als Operationalisierung wäre beispielsweise denkbar zu überprüfen, ob Befragte im Jahr nach dem verlassen der Haupt-/Real-/Sekundarschule eine Berufliche Ausbildung, einen weiteren Schulbesuch, eine Übergangsaktivität oder etwas anderes (Arbeitslosigkeit, ungelernt Jobben etc.) gemacht haben. Das Aufbereiten der Längsschnittdaten ist jedoch nicht ganz einfach. Ich habe mal quick and dirty ein codeschnipsel von einem meiner Datenaufbereitungsprojekte auf deine Fragestellung angepasst. Vielleicht hilft dir das ja als Grundlage.
********************************************************************************
* Do-File Übergang Schule in Ausbildung
* Hans Gerhardt
clear all
global neps_data "M:/group/DSI/NEPS/Erhebungsdaten_intern/"
********************************************************************************
global cohort "SC4"
global version "D_12-0-0"
global suf "$neps_data/SUF SC4/SUF SC4_D_12-0-0_20211206/Stata14"
********************************************************************************
* Biography-file als Grundlage für die Arbeit mit den Episodendaten
use "$suf/${cohort}_Biography_${version}", clear
********************************************************************************
* Informationen zur Schulbiografie aus spSchool
merge 1:m ID_t splink using "$suf/${cohort}_spSchool_${version}", ///
keep(match master) nogen ///
keepusing(subspell ts11204 ts11209 ts11209)
drop if subspell != 0 & sptype == 22 // ich nutze nur die harmonisierten/vollständigen Spells aus dem Schuldatensatz, diese sind als subspell = 0 abgelegt
drop subspell
// Besuchte Schulform / Schulabschluss
fre ts11204 ts11209
// Beispiel Operationalisierung: Was machen Befragte 9 Monate nach Hauptschulabschluss/MSA?
gen marker = 1 if inlist(ts11209,1,2,3) // markierung relevante Datenzeilen
// nur ersten Abschluss markieren
gen enddatum = ym(endy,endm)
bys ID_t marker (enddatum): replace marker = . if _n != 1 // nur ersten abschluss markieren
// Übertragung auf alle spells pro person, um in späteren Analyseschritten auf infos zurück greifen zu können
bys ID_t (marker): gen datum_erster_abschluss = enddatum[1]
bys ID_t (marker): gen art_erster_abschluss = ts11209[1]
bys ID_t (marker): gen note_erster_abschluss = ts11209[1]
format datum_erster_abschluss %tm
// Nur Episoden behalten, die früher 9 Monate nach letztem Abschluss angefangen haben und zu dem Zeitpunkt noch andauern
keep if ym(starty,startm) < (datum_erster_abschluss+9) & (datum_erster_abschluss+9)<= ym(endy,endm)
// Parallele Episoden identifizieren
bys ID_t: gen parallel_episodes = _N
fre parallel_episodes
fre sptype if parallel_episodes >= 2
list ID_t parallel_episodes sptype if parallel_episodes >= 2, sepby(ID_t)
* Entscheidung Welche der parallen Episoden soll gelöscht werden
* kleinere Prio = wird vorrangig behalten
fre spms
recode spms -55 = 2 2 = 3, gen(prio1)
fre sptype
recode sptype 24 = 1 23 = 2 22 = 3 25 = 4 27 = 5 29 = 6 26 = 7 30 = 8 99 = 9, gen(prio2)
// Eine Episode pro Person behalten
bys ID_t (prio1 prio2 splink): keep if _n == 1
drop parallel_episodes prio1 prio2 ts11209 ts11204 enddatum marker
** Was machen Befragte 9 Monate nach erstem Hauptschulabschluss/MSA?
fre sptype
** Jetzt könntest du Über spVocTrain auch noch genauere Angaben zur Art der Ausbildung ranmergen
merge 1:m ID_t splink using "$suf/${cohort}_spVocTrain_${version}", ///
keep(match master) nogen keepusing(relevante Variablen)
fre subspell
drop if subspell != 0 & sptype == 24 // ich nutze nur die harmonisierten Spells aus den anderen Spell-Datensätzen, diese sind als subspell = 0 abgelegt
Im pTarget-file liegen die Daten aus den sogenannten Übergangsmodulen. Die Befragten werden entsprechend ihrer Angaben zum Lebensverlauf (Episodenstruktur) nochmal speziell in die für die passenden Fragen zur aktuellen Situation gefiltert (Jahr vor dem Übergang, im ersten Jahr der Ausbildung, im letzten Jahr der Ausbildung, nach dem Übergang in den Job) und nochmal detailliert nach Merkmalen des Übergangs gefragt. Für die SC4 gibt es dafür leider noch keine Dokumentation, aber die Erhebung erfolgt in der SC3 sehr ähnlich und wird im Data-Manual der SC3 beschrieben (Kapital zu School-to-Training/Work Transitions). Das aktualisierte Data Manual ist fast fertig und soll zeitnah veröffentlicht werden. Die Frage die du im do-file aktuell verwendest ist eine dieser Fragen aus dem Modul zum Übergang in die Ausbildung, die den Befragten während ihrer Schulzeit gestellt werden.
Wie Tobias schon geschrieben hat, würde ich dir auch empfehlen im Querschnitt zu arbeiten. Das heißt, pro Person nur eine Zeile, und nicht mit allen Wellen zu arbeiten.
Ich hoffe ich konnte etwas weiterhelfen
Hans
Literaturangaben
Kleinert, C., & Schels, B. (2020). Zurück zur Norm? Kompromissbildung zwischen geschlechtstypischen und -untypischen Berufsaspirationen, Bewerbungs- und Ausbildungsberufen. Köln Z Soziol, 72(Suppl 1), 229–260. https://doi.org/10.1007/s11577-020-00668-1
Schels, B., Kleinert, C., Fischer-Browne, M. & Ahrens, L. (2022). Compromises between Occupational Aspirations and VET Occupations — a Contribution to the Reproduction of Social Inequalities?. Zeitschrift für Soziologie, 51(2), 154-173. https://doi.org/10.1515/zfsoz-2022-0011
